[qwertin]

вообщем, такая загвоздка:
2 обьекта(image к примеру) элементарно передвигаются при помощи данных событий-onkeypress и onkeydown
(у одного управление на стрелках, у другого на буквах соответственно):
image1.top:=image1.top+5; - для первого
image2.top:=image2.top+5; - 2-го;
но почему то они не хотят "ехать" одновременно, т.е. нажимаем на стрелки - Image "поехал", но image2 "ехать" не хочет и наоборот.
Что делать?

[Janom]

Сообщение от qwertin

вообщем, такая загвоздка:
2 обьекта(image к примеру) элементарно передвигаются при помощи данных событий-onkeypress и onkeydown
(у одного управление на стрелках, у другого на буквах соответственно):
image1.top:=image1.top+5; - для первого
image2.top:=image2.top+5; - 2-го;
но почему то они не хотят "ехать" одновременно, т.е. нажимаем на стрелки - Image "поехал", но image2 "ехать" не хочет и наоборот.
Что делать?

А ты уверен, что ты обе кнопки одновременно нажимешь (с точки зрения программы)?

[qwertin]

вообщем ,нажимая на кнопку первого компонента, прерывается движение второго предмета (при нажатой кнопке второго компонента)... хотелось бы видеть движение обоих компонентов одновременно при нажатых клавишах...

[AlexSku]

Ты столкнулся с действием микросхемы клавиатуры. Если клавиша нажата, то посылается её код и запускается таймер, потом через небольшую паузу клавиатура будет бесконца посылать код этой клавиши. Как только нажимается другая клавиша, от первой перестают приходить коды, а приходят от новой. Но можно опросить клавиатуру (сейчас не помню как. Наверняка есть в DirectInput), она фиксирует, какие клавиши нажаты, какие отпущены. Но можно и самому запоминать нажатие, а перемещения делать в событии таймера.

Нашёл: ф-я WinAPI GetKeyState(), посмотри справку.
Ещё можно GetKeyboardState (), выдаёт состояния всех клавиш.

[dr. F.I.N.]

На форме 2 компонента TShape и 1 TTimer

Код:

Form1.KeyPreview := true;
Timer1.Enable := true;
Timer1.Interval := {по желанию} 50;

Глобальная переменная:

Код:

var
  KeyDown: set of Byte;

И далее:

Код:

procedure TForm1.FormKeyDown(Sender: TObject; var Key: Word;
  Shift: TShiftState);
begin
  if Key in [37..40, 65, 68, 83, 87] then Include(KeyDown, Key);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  KeyDown := [];
end;

procedure TForm1.FormKeyUp(Sender: TObject; var Key: Word;
  Shift: TShiftState);
begin
  Exclude(KeyDown, Key);
end;

procedure TForm1.Timer1Timer(Sender: TObject);
var
  offX, offY: Integer;
begin
  offX := 0;
  offY := 0;
  if 87 in KeyDown then offY := offY - 5;
  if 65 in KeyDown then offX := offX - 5;
  if 83 in KeyDown then offY := offY + 5;
  if 68 in KeyDown then offX := offX + 5;
  Shape1.SetBounds(Shape1.Left + offX, Shape1.Top + offY, Shape1.Width, Shape1.Height);
  offX := 0;
  offY := 0;
  if 38 in KeyDown then offY := offY - 5;
  if 37 in KeyDown then offX := offX - 5;
  if 40 in KeyDown then offY := offY + 5;
  if 39 in KeyDown then offX := offX + 5;
  Shape2.SetBounds(Shape2.Left + offX, Shape2.Top + offY, Shape2.Width, Shape2.Height);
end;