[NekitoSSSS]

начал углубляться в сетевое программирование, и спуститься с Indy до WinSock
как пример для изучения хочу сделать софтину, которая будет авторизовываться на сайте (методом post. куки приходят, так что их тоже надо сохранять, и отправлять при последующих запросах... )
и брать кое какие данные... (парсить страницу это не проблема )
с GET знаком, с POST - не очень, т.к. пока что не получается правильно сформировывать данные для отправки и распарсивать принятые данные...

кто чем может помочь в изучении??!!
к поисковикам не посылать, слишком уж это для вас обыденно просто...

[NekitoSSSS]

особенно интересуют неблокирующие сокеты, а так же информация о том как отправлять, принимать и в цикле ожидать данные с сервера.
подскажите пожалуйста кто что знает((

p.s. все мы когда-то были нубами((

[NumLock]

ну если в цикле ожидать ответ сервера, то сокет должен быть блокируемым, имхо
пример автризации на одном форуме :

PHP код:

unit Unit1;

interface

uses
  ScktComp,
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
var
  clientsocket: TClientSocket;
  request: String;
  request_data: String;
  savetickcount: Cardinal;
  c: Char;
  response: String;

  username: String;
  password: String;

begin

  username:='**********';
  password:='**********';

  clientsocket:=TClientSocket.Create(Self);
  try
    clientsocket.ClientType:=ctBlocking;
    clientsocket.Port:=80;
    clientsocket.Host:='forum29.ru';
    clientsocket.Open;
    try
      //  post данные
      request_data:='vb_login_username='+username+'&vb_login_password='+password+'&cookieuser=1&s=&securitytoken=guest&do=login&vb_login_md5password=&vb_login_md5password_utf=';
      //  готовим post запрос
      request:='';
      request:=request+'POST /login.php?do=login HTTP/1.1'+#13#10;
      request:=request+'Host: forum29.ru'+#13#10;
      request:=request+'Connection: close'+#13#10;
      request:=request+'Proxy-Connection: close'+#13#10;
      request:=request+'User-Agent: Mozilla/4.0'+#13#10;
      request:=request+'Content-Type: application/x-www-form-urlencoded'+#13#10;
      request:=request+'Content-Length: '+IntToStr(Length(request_data))+#13#10;
      request:=request+#13#10;
      //  отсылаем серверу
      clientsocket.Socket.SendText(request);
      clientsocket.Socket.SendText(request_data);
      //  то что послали серверу
      Memo1.Lines.Add(request);
      Memo1.Lines.Add(request_data);
      Memo1.Lines.Add('--');
      //  теперь читаем его ответ
      //  читаем заголовок ответа
      //  1 мин таймаут
      savetickcount:=GetTickCount;
      response:='';
      while clientsocket.Socket.Connected and (GetTickCount-savetickcount<60000) do
      begin
        if clientsocket.Socket.ReceiveLength>0 then
        begin
          clientsocket.Socket.ReceiveBuf(c, 1);
          response:=response+c;
          if (Length(response)>=4) and (Copy(response, Length(response)-3, 4)=#13#10#13#10) then Break;
        end else Sleep(10);
      end;
      //  вот заголовок
      //  чтобы собрать куки обрабатываем строки с Set-Cookie
      //  response можно засунуть в отдельный TStrings, чтобы удобней было его парсить
      Memo1.Lines.Add(response);
      Memo1.Lines.Add('--');
      //  читаем страницу
      //  т.к. этот сервер передает чанками
      //  Transfer-Encoding: chunked
      //  ждем ответа макс 10 сек
      //  либо "руками" обрабатываем чанки и выходим когда все принято
      //  но это уже совсем другая история
      //  конечно проще когда есть Content-Length в заголовке, имхо
      savetickcount:=GetTickCount;
      response:='';
      while clientsocket.Socket.Connected and (GetTickCount-savetickcount<10000) do
      begin
        if clientsocket.Socket.ReceiveLength>0 then
        begin
          clientsocket.Socket.ReceiveBuf(c, 1);
          response:=response+c;
        end;
      end;
      //  вот страница
      Memo1.Lines.Add(response);
      Memo1.Lines.Add('--');
    finally
      clientsocket.Close;
    end;
  finally
    clientsocket.Free;
  end;
end;

end. 


[NumLock]

PHP код:

request_data:='vb_login_username='+username+'&vb_login_password='+password+'&cookieuser=1&s=&securitytoken=guest&do=login&vb_login_md5password=&vb_login_md5password_utf='; 


взято с формы авторизации на форуме

[NekitoSSSS]

эЭЭ чувак, ты похоже немного перепутал! мне нужна инфа про WinSock а не про TClientSocket (TClientSocket`Ы увеличивают размер проги на десятки килобайт, а мне нужно чисто на апи, чтоб прога весила не больше 60кб ... )
ну впринципе и за это спс)))

[NumLock]

упс. подумал, что основной вопрос все-таки про POST, поэтому и выдал как проще. если никто не ответит выдам на выходных на голом Windows Sockets 2 (постараюсь) сейчас лень

[Aristarh Dark]

Вообще-то разницы нет, подход-то правильный. А как там сокет создается - дело десятое.

[NumLock]

переделал предыдущий пример (только до чтения заголовка, остальное по аналогии):

PHP код:

unit Unit1;

interface

uses
  WinSock,
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
var
  WSAData: TWSAData;
  ErrorCode: Integer;
  FSocket: TSocket;
  HostEnt: PHostEnt;
  InAddr: TInAddr;
  FAddr: TSockAddrIn;
  Blocking: Longint;
  arg: Integer;

  request: String;
  request_data: String;
  savetickcount: Cardinal;
  c: Char;
  response: String;

  username: String;
  password: String;
begin
  username:='**********';
  password:='**********';

  ErrorCode:=WSAStartup($0101, WSAData);
  if ErrorCode<>0 then raise Exception.Create('WSAStartup');
  try
    FSocket:=socket(PF_INET, SOCK_STREAM, 0);
    if FSocket=INVALID_SOCKET then raise Exception.Create('socket');

    HostEnt:=gethostbyname('forum29.ru');
    FillChar(InAddr, SizeOf(InAddr), 0);
    if HostEnt<>nil then
    begin
      InAddr.S_un_b.s_b1:=HostEnt^.h_addr^[0];
      InAddr.S_un_b.s_b2:=HostEnt^.h_addr^[1];
      InAddr.S_un_b.s_b3:=HostEnt^.h_addr^[2];
      InAddr.S_un_b.s_b4:=HostEnt^.h_addr^[3];
    end else raise Exception.Create('gethostbyname');
    FAddr.sin_family:=PF_INET;
    FAddr.sin_addr:=InAddr;
    FAddr.sin_port:=htons(80);

    Blocking:=0;
    ioctlsocket(FSocket, FIONBIO, Blocking);

    ErrorCode:=connect(FSocket, FAddr, SizeOf(FAddr));
    if ErrorCode<>0 then raise Exception.Create('connect');

    try
      //  post данные
      request_data:='vb_login_username='+username+'&vb_login_password='+password+'&cookieuser=1&s=&securitytoken=guest&do=login&vb_login_md5password=&vb_login_md5password_utf=';
      //  готовим post запрос
      request:='';
      request:=request+'POST /login.php?do=login HTTP/1.1'+#13#10; 
      request:=request+'Host: forum29.ru'+#13#10; 
      request:=request+'Connection: close'+#13#10; 
      request:=request+'Proxy-Connection: close'+#13#10; 
      request:=request+'User-Agent: Mozilla/4.0'+#13#10;
      request:=request+'Content-Type: application/x-www-form-urlencoded'+#13#10; 
      request:=request+'Content-Length: '+IntToStr(Length(request_data))+#13#10; 
      request:=request+#13#10; 
      //  отсылаем серверу 

      send(FSocket, Pointer(request)^, Length(request), 0);
      send(FSocket, Pointer(request_data)^, Length(request_data), 0);

      //  то что послали серверу
      Memo1.Lines.Add(request);
      Memo1.Lines.Add(request_data);
      Memo1.Lines.Add('--');
      //  теперь читаем его ответ
      //  читаем заголовок ответа
      //  1 мин таймаут
      savetickcount:=GetTickCount;
      response:='';

      while GetTickCount-savetickcount<60000 do
      begin
        ioctlsocket(FSocket, FIONREAD, arg);
        if arg>0 then
        begin
          recv(FSocket, c, 1, 0);
          response:=response+c;
          if (Length(response)>=4) and (Copy(response, Length(response)-3, 4)=#13#10#13#10) then Break;
        end else Sleep(10);
      end;
      //  вот заголовок 
      //  чтобы собрать куки обрабатываем строки с Set-Cookie 
      //  response можно засунуть в отдельный TStrings, чтобы удобней было его парсить 
      Memo1.Lines.Add(response); 
      Memo1.Lines.Add('--');
    finally
      ErrorCode:=closesocket(FSocket);
      if ErrorCode<>0 then raise Exception.Create('closesocket');
    end;
  finally
    ErrorCode := WSACleanup;
    if ErrorCode<>0 then raise Exception.Create('WSACleanup');
  end;
end;

end. 


[NekitoSSSS]

результат работы твоего кода.. это нормально?!

[NumLock]

ну уж с кодировкой то сам. основную цель код выполняет.

[NekitoSSSS]

виновата кодировка о_О ? а почему тогда HTTP Analyzer не показывает что что-то вообще отправилось и принялось? или что-то другое посоветуешь для мониторинга траффика?

[NekitoSSSS]

да, кстати если закоментировать строку

Код:

if (Length(response)>=4) and (Copy(response, Length(response)-3, 4)=#13#10#13#10) then Break;

то данные приходят... правда не те конечно которые хотелось бы видеть, то есть виден только ответ... без заголовков...

[NumLock]

поставь точку останова на

PHP код:

response:=response+c; 


и см. что в "с" прихотит. правильней еще recv() сделать как if recv()>0

if recv(FSocket, c, 1, 0)>0 then response:=response+c;

[NekitoSSSS]

сори конечно, но после того как перенес данный код в D7 то все стало работать как часы, в т.ч. сниффер заметил активность проги ))) все, возвращаюсь обратно на D7 с этого тупого embarcadero RadStudio 2010

[NumLock]

а разобраться с RadStudio 2010 нет желания?