[Danielz]

Здравствуйте, народ.

Столкнулся с такой проблемой. В ходе работы проги происходит перемещение папки в другое место (копирование, затем удаление). Использую стандартные функции SysUtils. После выполнения процедуры перемещения, все успешно перемещается, ошибок нигде не возникает. Но есть одно НО. Остаётся пустая папка, доступ к которой отсутствует. После закрытия программы, папка пропадает. А нужно, чтобы пропадала сразу. Может кто сталкивался? Где собака зарыта?

[NumLock]

Сообщение от Danielz

Где собака зарыта?

в 13-ой строке кода

[poli-smen]

Сообщение от Danielz

Здравствуйте, народ.

Столкнулся с такой проблемой. В ходе работы проги происходит перемещение папки в другое место (копирование, затем удаление). Использую стандартные функции SysUtils. После выполнения процедуры перемещения, все успешно перемещается, ошибок нигде не возникает. Но есть одно НО. Остаётся пустая папка, доступ к которой отсутствует. После закрытия программы, папка пропадает. А нужно, чтобы пропадала сразу. Может кто сталкивался? Где собака зарыта?

Значит не закрыл хэндлы. Всегда освобождай ресурсы которые больше не нужны.

[Danielz]

Сообщение от poli-smen

Значит не закрыл хэндлы. Всегда освобождай ресурсы которые больше не нужны.

Как узнать - чего закрыть нужно?

[poli-smen]

Сообщение от Danielz

Как узнать - чего закрыть нужно?

Пройдись по исходнику и посмотри какие хэндлы захватываются, но не освобождаются.

[Danielz]

Сообщение от poli-smen

... посмотри какие хэндлы захватываются...

Мне вот это не совсем понятно. Точнее совсем не понятно. Я с этим раньше вообще не сталкивался.

[RusMaXXX]

ты хоть фрагмент кода показал!!! было бы проще искать ошибку

[Danielz]

Сообщение от RusMaXXX

ты хоть фрагмент кода показал!!! было бы проще искать ошибку

Код:

function MoveToArc(SourceFile, DestDir: string; Directory: boolean): boolean;
var
  FindFile: TSearchRec;
begin
  Result := True;
  // Создаем папку DestDir
  if not CreateDir(PWideChar(DestDir)) then
    if GetLastError <> 183 then
    begin
      Result := False;
      Exit;
    end;
  if Directory then
  begin
    // Создаем директорию SourceFile в папке DestDir
    if not CreateDir(PWideChar(DestDir + '\' + ExtractFileName(SourceFile))) then
      if GetLastError <> 183 then
      begin
        Result := False;
        Exit;
      end;
    if FindFirst(SourceFile + '\*.*', faanyfile, FindFile) = 0 then
    begin
      repeat
        if FindFile.Attr <> faDirectory then
          if not MoveToArc(SourceFile + '\' + FindFile.Name, DestDir + '\' + ExtractFileName(SourceFile), False) then
          begin
            Result := False;
            Exit;
          end;
      until FindNext(FindFile) <> 0;
      FindClose(FindFile);
      if not RemoveDir(PWideChar(SourceFile)) then
        Result := False;
    end;
  end
  else
  begin
    if CopyFile(PWideChar(SourceFile), PWideChar(DestDir + '\' + ExtractFileName(SourceFile)), True) then
    begin
      if not DeleteFile(SourceFile) then
        Result := False;
    end
    else
      Result := False;
  end;
end;

[poli-smen]

Обращает на себя внимание вот этот кусок кода:

Код:

    if FindFirst(SourceFile + '\*.*', faanyfile, FindFile) = 0 then
    begin
      repeat
        if FindFile.Attr <> faDirectory then
          if not MoveToArc(SourceFile + '\' + FindFile.Name, DestDir + '\' + ExtractFileName(SourceFile), False) then
          begin
            Result := False;
            Exit;
          end;
      until FindNext(FindFile) <> 0;
      FindClose(FindFile);
      if not RemoveDir(PWideChar(SourceFile)) then
        Result := False;
    end;

Если функция MoveToArc возвращает False, то сразу же происходит выход из процедуры и функция FindClose (которая закрывает поисковой хендл) не выполнится и хэндл будет висеть незакрытым пока не закроем всё приложение и винда сама не освободит все хэндлы захваченые им.

[M.A.D.M.A.N.]

юзай try finally.

[poli-smen]

Кстати почему так странно делается перемещение файла?:

Сообщение от Danielz

Код:

    if CopyFile(PWideChar(SourceFile), PWideChar(DestDir + '\' + ExtractFileName(SourceFile)), True) then
    begin
      if not DeleteFile(SourceFile) then
        Result := False;
    end
    else
      Result := False;

Для перемещения/переименования файлов есть функция RenameFile (оболочка над API-функцией MoveFile)

[Danielz]

Сообщение от poli-smen

Обращает на себя внимание вот этот кусок кода:

Код:

    if FindFirst(SourceFile + '\*.*', faanyfile, FindFile) = 0 then
    begin
      repeat
        if FindFile.Attr <> faDirectory then
          if not MoveToArc(SourceFile + '\' + FindFile.Name, DestDir + '\' + ExtractFileName(SourceFile), False) then
          begin
            Result := False;
            Exit;
          end;
      until FindNext(FindFile) <> 0;
      FindClose(FindFile);
      if not RemoveDir(PWideChar(SourceFile)) then
        Result := False;
    end;

Если функция MoveToArc возвращает False, то сразу же происходит выход из процедуры и функция FindClose (которая закрывает поисковой хендл) не выполнится и хэндл будет висеть незакрытым пока не закроем всё приложение и винда сама не освободит все хэндлы захваченые им.

Согласен. Упустил. Но дело не в этом.

[poli-smen]

Сообщение от Danielz

Согласен. Упустил. Но дело не в этом.

И всёже переделай этот кусок кода с использованием конструкции try...finally (как советует M.A.D.M.A.N.), для гарантированного освобождения хэндла.

В твоём случае это будет так:

Код:

if FindFirst(SourceFile + '\*.*', faanyfile, FindFile) = 0 then
begin
  try
    repeat
      if FindFile.Attr <> faDirectory then
        if not MoveToArc(SourceFile + '\' + FindFile.Name, DestDir + '\' + ExtractFileName(SourceFile), False) then
        begin
          Result := False;
          Exit;
        end;
    until FindNext(FindFile) <> 0;
  finally
    FindClose(FindFile);
  end;
  if not RemoveDir(PWideChar(SourceFile)) then
    Result := False;
end;

Если после этих изменений будет оставаться "пустая папка, доступ к которой отсутствует", значит ты не закрываешь хэндл ещё в другом месте (исходник которого ты не публиковал).

[Danielz]

Сообщение от poli-smen

Если после этих изменений будет оставаться "пустая папка, доступ к которой отсутствует", значит ты не закрываешь хэндл ещё в другом месте (исходник которого ты не публиковал).

Видать так и есть. Я думал, может какими-то средствами можно отследить эти потоки приложения, а не руками и глазами.

[Danielz]

Главное, что RemoveDir true выдает. И вроде как удаляет.